blob: 0a42e474862214f3f9037e0847ce8b5087d41285 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
_pkgname=seriation
_pkgver=1.5.5
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Infrastructure for Ordering Objects Using Seriation"
arch=(x86_64)
url="https://cran.r-project.org/package=$_pkgname"
license=('GPL-3.0-only')
depends=(
r-ca
r-colorspace
r-foreach
r-gclus
r-qap
r-registry
r-tsp
r-vegan
)
makedepends=(
gcc-fortran
)
checkdepends=(
r-dbscan
r-dendextend
r-ga
r-rtsne
r-testthat
r-umap
)
optdepends=(
r-dbscan
r-dendextend
r-dendser
r-doparallel
r-ga
r-ggplot2
r-keras
r-rtsne
r-scales
r-smacof
r-tensorflow
r-testthat
r-umap
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('4bec976b98f62f19d5e4c7b5be4e2ea2')
b2sums=('6f9b30e349445ec2b7e618b17f4efeda5a8ad1e401c5c137bba3012d83a9f48efc165bc5732669255146cce99b14548fe723769b824d891130e02de65d762d38')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|