blob: 381b4ca5be7edf31f1eb215eb3716e9a5c0c12d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
# Contributor: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
_pkgname=sourcetools
_pkgver=0.1.7-1
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=4
pkgdesc="Tools for Reading, Tokenizing and Parsing R Code"
arch=(x86_64)
url="https://cran.r-project.org/package=$_pkgname"
license=('MIT')
depends=(
r
)
checkdepends=(
r-testthat
)
optdepends=(
r-testthat
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('dd4a9af00de6e874802f6e6622b774fb')
b2sums=('c74d603d6878aae3915cb90a28f08e8930bf64c72b46d0d139489aea561f40cd09cb56fe40bec31a147856cde6e54f49d493dc436448e14b544b6dc92b40b7c2')
prepare() {
# skip a test that expects certain files in home directory
sed -i '/"files in packages are tokenized without errors"/a\ \ skip("bad test")' \
"$_pkgname/tests/testthat/test-tokenize.R"
}
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|