blob: 732de2c21f88c302911705dea07dc52bdf014b5b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=spaSim
_pkgver=1.6.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Spatial point data simulator for tissue images"
arch=(any)
url="https://bioconductor.org/packages/$_pkgname"
license=('Artistic-2.0')
depends=(
r-dplyr
r-ggplot2
r-rann
r-spatialexperiment
r-spatstat.geom
r-spatstat.random
r-summarizedexperiment
)
checkdepends=(
r-testthat
)
optdepends=(
r-biocstyle
r-knitr
r-markdown
r-refmanager
r-rmarkdown
r-sessioninfo
r-testthat
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('ceec90576a23f42e2f8a77222b7f1eac')
b2sums=('845e80f50921b0fd0763e32f122211c40320df713e7757c586a5420d5e7552ce038dd9fb459c45157c417320533ce1a5f3a655d5e9aecadbb76a1d4944473d28')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|