blob: 2f1923e110c8868532f23d9b53ff0cdbfa40935e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=syntenet
_pkgver=1.6.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Inference And Analysis Of Synteny Networks"
arch=(x86_64)
url="https://bioconductor.org/packages/$_pkgname"
license=('GPL-3.0-only')
depends=(
r-biocparallel
r-biostrings
r-genomicranges
r-ggnetwork
r-ggplot2
r-igraph
r-intergraph
r-networkd3
r-pheatmap
r-rcolorbrewer
r-rcpp
r-rlang
r-rtracklayer
)
makedepends=(
r-testthat
)
checkdepends=(
r-xml2
)
optdepends=(
r-biocstyle
r-covr
r-ggtree
r-knitr
r-labdsv
r-rmarkdown
r-testthat
r-xml2
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('c163717eec18f17589d6f47ddcb3221e')
b2sums=('23797a49f8597d3dd358e6b16bbb94b50886071b22640f8b2266e0ec8a389ab23773d779ec21ea6b0a5d63c7a1b6a05f464e76c5abf28682f1d5fce0a59182e0')
prepare() {
# skip tests that cause a coredump
sed -i '1i skip("dumps core")' "$_pkgname/tests/testthat/test-03_synteny_detection.R"
}
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|