blob: 3ecd8d7605c0fccdf7178dfa7750cec559944e60 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
_pkgname=tiledb
_pkgver=0.26.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Modern Database Engine for Complex Data Based on Multi-Dimensional Arrays"
arch=(x86_64)
url="https://cran.r-project.org/package=$_pkgname"
license=('MIT')
depends=(
r-nanoarrow
r-nanotime
r-rcpp
r-spdl
tiledb
)
makedepends=(
r-rcppint64
)
checkdepends=(
r-arrow
r-data.table
r-nycflights13
r-palmerpenguins
r-tinytest
)
optdepends=(
r-arrow
r-bit64
r-curl
r-data.table
r-nycflights13
r-palmerpenguins
r-simplermarkdown
r-tibble
r-tinytest
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz"
"skip-tests.patch")
md5sums=('2e3af5fee4164969caa18fdbabfe4c64'
'65589ce8628e97f3ef75905ba16cd8fa')
b2sums=('684b4a1e06afafbccc6fef3716cc69b20539cff2bbb15b1e011f2d8e8da50ab704fb619d110b4f42efc9c6d5304dbab45da8d68b1e320771a4ba437490416b10'
'd82cae045055f52ca11160181df950e4f44773cac3ccd8c04de78f8ba5901b46d9095d9439b86ce78ba0804d98ef9ee6fdffc3ed76b7cda3d1e5c0ffd9b22449')
prepare() {
# skip tests that make a coredump
patch -Np1 -i skip-tests.patch
}
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" Rscript --vanilla tinytest.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|