PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Josip Ponjavic <josipponjavic at gmail dot com>

pkgname=rapid-photo-downloader-bzr
pkgver=0.9.14.r1121
pkgrel=1
pkgdesc="Photo and video downloader"
arch=('any')
url="http://www.damonlynch.net/rapid/"
license=('GPL3')
depends=('desktop-file-utils' 'gstreamer' 'hicolor-icon-theme'
         'libgexiv2' 'libgudev' 'libnotify' 'perl-image-exiftool'
         'python-arrow' 'python-colour' 'python-dateutil'
         'python-distutils-extra' 'python-easygui' 'python-gobject'
         'python-gphoto2' 'python-psutil' 'python-pymediainfo' 'python-pyqt5'
         'python-pyzmq' 'python-rawkit' 'python-sortedcontainers'
         'python-tornado' 'python-xdg' 'qt5-imageformats' 'udisks2')
makedepends=('bzr' 'gobject-introspection' 'intltool' 'python-setuptools')
optdepends=('gst-libav: for extra video thumbnails'
            'gst-plugins-good: for extra video thumbnails'
            'python-colorlog: for color output'
            'python-pyprind: for progressbar')
provides=("${pkgname%-*}=${pkgver%.*}")
conflicts=("${pkgname%-*}")
source=('rapid::bzr+https://code.launchpad.net/~dlynch3/rapid/zeromq_pyqt')
sha256sums=('SKIP')

pkgver() {
  cd rapid
  version=$(grep -oP "__version__ = '\K[^']+" raphodo/__about__.py)
  printf "%s.r%s" "$version" "$(bzr revno)"
}

build() {
  cd rapid
  python setup.py build
}

package() {
  cd rapid
  python setup.py install --root="$pkgdir" --optimize=1
}