PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer:‌  dreieck          (https://aur.archlinux.org/account/dreieck)
# Contributor: Daniel Menelkir  (https://aur.archlinux.org/account/Menelkir)

_pkgname=raplcap
pkgname="${_pkgname}"
pkgver=0.9.0
pkgrel=3
pkgdesc="RAPL power capping C interface with multiple implementations."
arch=('x86_64')
url="https://github.com/powercap/raplcap"
license=('custom:BSD')
depends=(
  'glibc'
  'powercap'
)
makedepends=(
  'cmake'
)
source=(
  "https://github.com/powercap/${pkgname}/archive/refs/tags/v${pkgver}.tar.gz"
)
sha256sums=(
  '645f12be75d731b2ce847356a0d32e9c8c0a44791b8337185a383656ffc92121'
)

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  mkdir -p _build
  cd _build
  cmake \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DRAPLCAP_CONFIGURE_MSR_EXTRA=ON \
    ..
  make
}

check() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  cd _build
  make test
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  cd _build
  make DESTDIR="${pkgdir}" install

  cd "${srcdir}/${pkgname}-${pkgver}"
  for _docfile in AUTHORS README.md RELEASES.md; do 
    install -Dvm644 "${_docfile}" "${pkgdir}/usr/share/doc/${_pkgname}/${_docfile}"
  done
  install -Dvm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  ln -svr "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE" "${pkgdir}/usr/share/doc/${_pkgname}/LICENSE"
}