blob: a654798ddeb38d466e3fa7c1e39bc3d590114482 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor: Chris Nixon <chris.nixon@sigma.me.uk>
pkgname=remacs
pkgver=0.1
pkgrel=1
epoch=1
pkgdesc='Emacs with parts of it written in Rust'
arch=(x86_64)
url='https://github.com/remacs/remacs'
license=(GPL)
depends=(gnutls gpm libxml2)
makedepends=(cargo clang git rustup setconf)
source=("git+https://github.com/remacs/remacs#tag=$pkgver")
sha256sums=('SKIP')
prepare() {
cd $pkgname
./autogen.sh
# Use full path to remacs and remacsclient
setconf etc/remacs.service ExecStart '/usr/bin/remacs --fg-daemon'
setconf etc/remacs.service ExecStop '/usr/bin/remacsclient --eval "(kill-emacs)"'
}
build() {
cd $pkgname
export LC_ALL=C
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib \
--localstatedir=/var \
--mandir=/usr/share/man \
--infodir=/usr/share/info \
--with-sound=no \
--with-modules \
--without-xft \
--without-gconf \
--without-gsettings \
--without-cairo \
--without-xwidgets \
--without-makeinfo \
--without-x \
--enable-link-time-optimization
make
}
package() {
make -C "$pkgname" DESTDIR="$pkgdir" install-strip
# avoid conflicts with other packages
rm "$pkgdir/usr/"{bin/{ctags,etags,ebrowse},share/man/man1/{ctags,etags,ebrowse}.1.gz}
mv "$pkgdir/usr/share/man/man1/"{e,re}macs.1.gz
mv "$pkgdir/usr/share/man/man1/"{e,re}macsclient.1.gz
rm -r "$pkgdir/usr/share/info"
# skip /var/games, /usr/share/pixmaps and /usr/share/applications
rm -rf "$pkgdir/"{var/games,usr/share/{pixmaps,applications}}
# fix permissions
find "$pkgdir"/usr/share/remacs/ -exec chown root:root {} \;
}
# vim: ts=2 sw=2 et:
|