aboutsummarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9db457c59bec12a56f9d2a9fb22ca7ad1dd45d11 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: Charles Leclerc <charles@la-mouette.net>

pkgname=reposilite
pkgver=3.5.14
pkgrel=1
pkgdesc="Lightweight repository manager for Maven artifacts. It is a simple solution to replace managers like Nexus, Archiva or Artifactory."
arch=(any)
url="https://reposilite.com"
license=('Apache')
depends=('java-runtime-headless>=11')
source=("https://maven.reposilite.com/releases/com/reposilite/$pkgname/$pkgver/$pkgname-$pkgver-all.jar"
        "$pkgname.service"
        "$pkgname.sysusers"
        "$pkgname.tmpfiles"
        "$pkgname.env"
        "$pkgname.wrapper")
sha256sums=('a995d8a73e920570c18fc73421991f560c4415effe0f13297612c9b2392cf1c3'
            '1e543e7ef39d64ae683156aaa6aad8f164f30de999d15717416410e1750b9a8e'
            '92ccfeff429aa4757ef353677dd99ad7aebe7483d4824706a27250e81efd6323'
            '9587fa49dd66d5f31dee33aa1a9da269a34666b63f62e2550a66c3bc1d397aa7'
            '7869b2925d6d2a897148b282af02992d7b4c5cfb6e7f01f0a277633689614c11'
            '2f7cd3fdada1ba51da3259a2ad7ef6bbdbb5fea5023c8fcc78d4d5c19ff569d3')
backup=('etc/reposilite/configuration.cdn'
        'etc/reposilite/default.env')

package() {
  install -Dm 644 $pkgname.service -t "${pkgdir}/usr/lib/systemd/system"
  install -Dm 644 $pkgname.sysusers "${pkgdir}/usr/lib/sysusers.d/$pkgname.conf"
  install -Dm 644 $pkgname.tmpfiles "${pkgdir}/usr/lib/tmpfiles.d/$pkgname.conf"
  install -Dm 644 "$pkgname-$pkgver-all.jar" "$pkgdir/usr/share/java/$pkgname/$pkgname.jar"
  install -Dm 644 $pkgname.env "${pkgdir}/etc/reposilite/default.env"
  java -jar "$pkgdir/usr/share/java/$pkgname/$pkgname.jar" -wd "${pkgdir}/etc/reposilite" -gc configuration.cdn
  install -Dm 755 $pkgname.wrapper "${pkgdir}/usr/bin/reposilite"
}