blob: fee880c565461a2204657467a21d475320ce1051 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
pkgname=reshape
pkgver=0.6.1
pkgrel=1
pkgdesc='A zero-downtime schema migration tool for PostgreSQL'
arch=('x86_64')
url='https://github.com/fabianlindfors/reshape'
license=('MIT')
depends=('gcc-libs')
makedepends=('git' 'rust')
options=('!lto')
_commit='d74ab4f34fbd777c5086de4f766eb635ad3864e7'
source=("$pkgname::git+$url.git#commit=$_commit")
b2sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/^v//'
}
prepare() {
cd "$pkgname"
cargo fetch --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname"
cargo build --frozen --release
}
package() {
cd "$pkgname"
# binary
install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.md
}
|