blob: a27c8eb825c2cc13eee7359766755fbc3611e326 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Maintainer:
# Contributor: Andrea Feletto <andrea@andreafeletto.com>
: ${_branch:=next-wlroots}
: ${_ver_wlr:=0.19}
_pkgname="river"
pkgname="$_pkgname-noxwayland-git"
pkgver=0.3.9.r7.gee1e36c
pkgrel=1
pkgdesc="A dynamic tiling wayland compositor"
url='https://codeberg.org/river/river'
license=('GPL-3.0-only')
arch=('x86_64')
depends=(
'libevdev'
'libinput'
'libxkbcommon'
'mesa'
'pixman'
'sh'
'wayland'
"wlroots${_ver_wlr}"
)
makedepends=(
'git'
'scdoc'
'wayland-protocols'
'zig'
)
optdepends=(
'polkit: access seat through systemd-logind'
)
provides=("$_pkgname")
conflicts=("$_pkgname")
_pkgsrc="codeberg.$_pkgname"
source=("$_pkgsrc"::"git+$url.git#branch=$_branch")
sha256sums=('SKIP')
prepare() {
# PACKAGING.md -> build.zig.zon
for i in $(grep '\.url' "$_pkgsrc"/build.zig.zon | sed -E 's&^.* = "(\S+)".*$&\1&'); do
zig fetch --global-cache-dir ./zig-global-cache "$i"
done
}
pkgver() {
cd "$_pkgsrc"
local _tag=$(git tag | sort -rV | head -1)
local _version"=${_tag#v}"
local _revision=$(git rev-list --count --cherry-pick "$_tag"...HEAD)
local _hash=$(git rev-parse --short=7 HEAD)
printf '%s.r%s.g%s' "${_version:?}" "${_revision:?}" "${_hash:?}"
}
_zig_options() {
_zig_options=(
--summary all
--prefix /usr
--search-prefix /usr
--global-cache-dir ../zig-global-cache
--system ../zig-global-cache/p
-Dtarget=native-linux.6.1-gnu.2.38
-Dcpu=baseline
-Dpie
-Doptimize=ReleaseSafe
)
}
build() {
_zig_options
cd "$_pkgsrc"
DESTDIR="build" zig build "${_zig_options[@]}"
}
check() {
_zig_options
cd "$_pkgsrc"
zig build test "${_zig_options[@]}"
}
package() {
cd "$_pkgsrc"
cp -a build/* "$pkgdir"
install -Dm644 contrib/river.desktop -t "$pkgdir/usr/share/wayland-sessions/"
mkdir -pm755 "$pkgdir/usr/share/$_pkgname"
cp -fr example "$pkgdir/usr/share/$_pkgname/"
}
|