blob: 9d3c485eaf3fdabe7d7c1554e9aeb6f7b65dac3f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Torsten Keßler <tpkessler at archlinux dot org>
# Contributor: acxz <akashpatel2008 at yahoo dot com>
pkgname=rocm-bandwidth-test
pkgver=5.7.1
pkgrel=1
pkgdesc="Bandwidth test for ROCm"
arch=('x86_64')
url="https://github.com/RadeonOpenCompute/rocm_bandwidth_test"
license=('custom:NCSAOSL')
depends=('hsa-rocr')
makedepends=('cmake')
source=("$pkgname-$pkgver.tar.gz::$url/archive/rocm-$pkgver.tar.gz"
"$pkgname-hsa-include.patch")
sha256sums=('7426ef1e317b8293e4d6389673cfa8c63efb3f7d061e2f50a6f0b1b706e2a2a7'
'8c3be607d36fb5aa01f770c244c5d4088dffddf879a21a9e0ac80d6dbcd2dbdf')
_dirname="$(basename "$url")-$(basename "${source[0]}" .tar.gz)"
prepare() {
cd "$_dirname"
patch -Np1 -i "$srcdir/$pkgname-hsa-include.patch"
}
build() {
cmake \
-Wno-dev \
-B build \
-DCMAKE_BUILD_TYPE=None \
-S "$_dirname" \
-DCMAKE_INSTALL_PREFIX=/opt/rocm
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
install -Dm644 "$_dirname/LICENSE.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|