PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Erica Marigold <hi@devcomp.xyz>

pkgname=rojo-git
pkgver=7.4.4.r0.g5bd3c74d
pkgrel=1
pkgdesc="[Latest Git Commit] Rojo enables Roblox developers to use professional-grade software engineering tools"
arch=(x86_64 aarch64)
conflicts=(rojo rojo-bin)
url="https://rojo.space/"
license=(MPL2)
depends=(gcc-libs glibc)
makedepends=(cargo git)
provides=(rojo)
options=(!lto)
source=("git+https://github.com/rojo-rbx/rojo.git")
sha256sums=('SKIP')

pkgver() {
  cd rojo
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd rojo
  git checkout 7.4.x
  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}

build() {
  cd rojo 
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo build --frozen --release
}

check() {
  cd rojo 
  export RUSTUP_TOOLCHAIN=stable
  cargo test --locked --verbose
}


package() {
  cd rojo
  install -Dm755 -t ${pkgdir}/usr/bin target/release/rojo
}