PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

pkgdesc="ROS - This package contains generic definitions of geometric shapes and bodies."
url='http://wiki.ros.org/geometric_shapes'

pkgname='ros-noetic-geometric-shapes'
pkgver='0.7.2'
arch=('i686' 'x86_64' 'aarch64' 'armv7h' 'armv6h')
pkgrel=1
license=('BSD')

ros_makedepends=(
    ros-noetic-resource-retriever
    ros-noetic-eigen-stl-containers
    ros-noetic-catkin
    ros-noetic-octomap
    ros-noetic-shape-msgs
    ros-noetic-random-numbers
    ros-noetic-visualization-msgs
)
makedepends=(
    cmake
    ros-build-tools
    ${ros_makedepends[@]}
    qhull
    assimp
    eigen
    boost
    console-bridge
    pkg-config
)

ros_depends=(
    ros-noetic-resource-retriever
    ros-noetic-eigen-stl-containers
    ros-noetic-octomap
    ros-noetic-shape-msgs
    ros-noetic-random-numbers
    ros-noetic-visualization-msgs
)
depends=(
    ${ros_depends[@]}
    assimp
    boost
    eigen
    console-bridge
    qhull
)

_dir="geometric_shapes-${pkgver}"
source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/ros-planning/geometric_shapes/archive/${pkgver}.tar.gz")
sha256sums=('542028d17daa1e307eb14e9f81c9a75bce64428d31c10ab4d977cdbc70bcea01')

build() {
    # Use ROS environment variables
    source /usr/share/ros-build-tools/clear-ros-env.sh
    [ -f /opt/ros/noetic/setup.bash ] && source /opt/ros/noetic/setup.bash

    # Create build directory
    [ -d ${srcdir}/build ] || mkdir ${srcdir}/build
    cd ${srcdir}/build

    # Build project
    cmake ${srcdir}/${_dir} \
          -DCATKIN_BUILD_BINARY_PACKAGE=ON \
          -DCMAKE_INSTALL_PREFIX=/opt/ros/noetic \
          -DPYTHON_EXECUTABLE=/usr/bin/python \
          -DSETUPTOOLS_DEB_LAYOUT=OFF
    make
}

package() {
    cd "${srcdir}/build"
    make DESTDIR="${pkgdir}/" install
}