blob: 646c6f11b86ea8d6524809c11da78cc29675afe6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=rpm-tools-git
pkgver=4.18.1.r492.g021a7d3aa
pkgrel=1
pkgdesc="RPM Package Manager"
arch=('i686' 'x86_64')
url="https://rpm.org/"
license=('GPL')
depends=('glibc' 'elfutils' 'file' 'libarchive' 'libcap' 'lmdb' 'lua' 'nss' 'popt' 'zstd')
makedepends=('git' 'python')
provides=("rpm-tools=$pkgver" 'rpmextract')
conflicts=('rpm-tools' 'rpmextract')
source=("git+https://github.com/rpm-software-management/rpm.git"
"rpmextract.sh::https://gitlab.archlinux.org/archlinux/packaging/packages/rpm-tools/-/raw/main/rpmextract.sh")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "rpm"
_tag=$(git tag -l --sort -v:refname | grep -E '^rpm-[0-9\.]+-release' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^rpm-//;s/-release//'
}
build() {
cd "rpm"
./autogen.sh --noconfigure
./configure \
--prefix="/usr" \
--enable-python \
--with-cap
make
}
check() {
cd "rpm"
make check
}
package() {
cd "rpm"
make DESTDIR="$pkgdir" install
install -Dm755 "$srcdir/rpmextract.sh" -t "$pkgdir/usr/bin"
rm -rf "$pkgdir/usr/var"
}
|