blob: b76ce53411457cbd828b61d3fada470b0bb73b11 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Mario Finelli <mario at finel dot li>
_gemname=benchmark-ips
pkgname=ruby-$_gemname
pkgver=2.10.0
pkgrel=1
pkgdesc="Provides iteration per second benchmarking for Ruby"
arch=(any)
url=https://github.com/evanphx/benchmark-ips
license=(MIT)
depends=(ruby)
checkdepends=(ruby-bundler ruby-minitest)
makedepends=(rubygems ruby-rdoc ruby-rake)
options=(!emptydirs)
source=(https://github.com/evanphx/benchmark-ips/archive/v$pkgver/$_gemname-$pkgver.tar.gz)
sha256sums=('6ee25509e1baf0cc9a3d791bdebffc4811f575c2f6036783645ec6ff8cab995a')
prepare() {
cd $_gemname-$pkgver
sed -i 's|~>|>=|g' Gemfile
sed -i 's/git ls-files --/find/' ${_gemname}.gemspec
}
build() {
cd $_gemname-$pkgver
gem build ${_gemname}.gemspec
}
check() {
cd $_gemname-$pkgver
rake
}
package() {
cd $_gemname-$pkgver
local _gemdir="$(gem env gemdir)"
gem install \
--ignore-dependencies \
--no-user-install \
-i "$pkgdir/$_gemdir" \
-n "$pkgdir/usr/bin" \
$_gemname-$pkgver.gem
rm -rf "$pkgdir/$_gemdir/cache"
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm0644 History.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG"
}
# vim: set ts=2 sw=2 et:
|