PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Mario Finelli <mario at finel dot li>
pkgname=ruby-bump
pkgver=0.10.0
_commit=73c206174ca02549d120402b9a007db0d0bc9699
pkgrel=6
pkgdesc='Bump your gem version file'
arch=(any)
url='https://github.com/gregorym/bump'
license=(MIT)
depends=(
  ruby
)
makedepends=(
  git
  ruby-rdoc
)
checkdepends=(
  ruby-bundler
  ruby-byebug
  ruby-rake
  ruby-rspec
  ruby-rubocop
)
options=(!emptydirs)
source=(git+https://github.com/gregorym/bump.git#commit=$_commit)
sha256sums=('SKIP')

prepare() {
  cd bump
  git config user.email "pony@arch"
  git config user.name "Lucky Pony"
}

build() {
  local _gemdir="$(gem env gemdir)"
  cd bump
  gem build bump.gemspec
  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "../tmp_install/$_gemdir" \
    --bindir "../tmp_install/usr/bin" \
    bump-$pkgver.gem
  find "../tmp_install/$_gemdir/gems/" \
    -type f \
    \( \
        -iname "*.o" -o \
        -iname "*.c" -o \
        -iname "*.so" -o \
        -iname "*.time" -o \
        -iname "gem.build_complete" -o \
        -iname "Makefile" \
    \) \
    -delete
  rm -r ../tmp_install/$_gemdir/cache
}

check() {
  local _gemdir="$(gem env gemdir)"
  cd bump
  GEM_HOME="../tmp_install/$_gemdir" rake spec
}

package() {
  cd bump
  cp -a ../tmp_install/* "$pkgdir"/
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
}