blob: 4a442b472ec6abaca0d6ee8ba15c04fc79d73a21 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Mario Finelli <mario at finel dot li>
_gemname=rubocop-ast
pkgname=ruby-${_gemname}
pkgver=1.23.0
pkgrel=1
pkgdesc="RuboCop's AST extensions and NodePattern functionality"
arch=(any)
depends=(ruby ruby-parser)
checkdepends=(ruby-bundler ruby-rspec)
makedepends=(rubygems ruby-rake ruby-rdoc ruby-racc ruby-oedipus_lex ruby-bump)
url=https://github.com/rubocop/rubocop-ast
license=(MIT)
options=(!emptydirs)
source=(https://github.com/rubocop/${_gemname}/archive/v$pkgver/$_gemname-$pkgver.tar.gz)
sha256sums=('cf9a4044c839f87a3559d211fde0614566e4bb75013f303035b5f20732f08422')
prepare() {
cd $_gemname-$pkgver
sed -i 's|git ls-files|find|' ${_gemname}.gemspec
sed -i '/simplecov/d' Gemfile
}
build() {
cd $_gemname-$pkgver
RUBOCOP_VERSION=none rake generate
gem build ${_gemname}.gemspec
}
check() {
cd $_gemname-$pkgver
RUBOCOP_VERSION=none rake spec
}
package() {
cd $_gemname-$pkgver
local _gemdir="$(gem env gemdir)"
gem install \
--ignore-dependencies \
--no-user-install \
-i "$pkgdir/$_gemdir" \
-n "$pkgdir/usr/bin" \
$_gemname-$pkgver.gem
rm -rf "$pkgdir/$_gemdir/cache"
install -Dm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -Dm0644 CHANGELOG.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"
}
# vim: set ts=2 sw=2 et:
|