blob: cd508193ac33ba02f3cbf594f373ea7590a3ac9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Jonne Haß <me@jhass.eu>
# Contributor: Thomas Dziedzic <gostrc@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>
# Contributor: Jeramy Rutley <jrutley@gmail.com>
pkgname=ruby2.2
pkgver=2.2.10
pkgdesc='An object-oriented language for quick and easy programming'
pkgrel=1
arch=(i686 x86_64)
url='http://www.ruby-lang.org/en/'
license=(BSD custom)
depends=(gdbm openssl-1.0 libffi libyaml gmp zlib)
optdepends=('tk: for Ruby/TK')
makedepends=(gdbm openssl libffi doxygen graphviz libyaml ttf-dejavu tk)
options=(!emptydirs)
source=(https://cache.ruby-lang.org/pub/ruby/${pkgver:0:3}/ruby-${pkgver}.tar.xz gcc7.patch)
prepare() {
cd ruby-${pkgver}
patch -p1 < ../gcc7.patch
}
build() {
cd ruby-${pkgver}
export PKG_CONFIG_PATH=/usr/lib/openssl-1.0/pkgconfig
PKG_CONFIG=/usr/bin/pkg-config ./configure \
--prefix=/opt/ruby2.2 \
--program-suffix=-2.2 \
--sysconfdir=/etc \
--localstatedir=/var \
--sharedstatedir=/var/lib \
--libexecdir=/usr/lib/ruby \
--enable-shared \
--disable-rpath \
--with-dbm-type=gdbm_compat
make ruby
}
check() {
cd ruby-${pkgver}
make test
}
package() {
cd ruby-${pkgver}
make DESTDIR="${pkgdir}" install-nodoc
install -dm755 $pkgdir/usr/bin
install -dm755 $pkgdir/usr/lib
for i in erb irb rdoc ri ruby testrb rake gem; do
ln -s /opt/$pkgname/bin/$i-2.2 $pkgdir/usr/bin/$i-2.2
ln -s /opt/$pkgname/bin/$i-2.2 $pkgdir/opt/$pkgname/bin/$i
done
ln -s /opt/$pkgname/lib/libruby.so.2.2 $pkgdir/usr/lib/libruby.so.2.2
install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
install -D -m644 BSDL "${pkgdir}/usr/share/licenses/$pkgname/BSDL"
}
sha256sums=('bf77bcb7e6666ccae8d0882ea12b05f382f963f0a9a5285a328760c06a9ab650'
'9647f5c9755358d2997a14c6fce17bd3ee898dc1ad22b5f93dcf51d9d630ad1f')
|