blob: 014de877ab7ace6ebfd40ed4953f0bfdf5b21d6d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: SteamedFish <steamedfish@hotmail.com>
pkgname=rx888-stream-git
_pkgname=rx888_stream
pkgver=r16.b699542
pkgrel=1
pkgdesc="command line utility to stream samples from RX888"
arch=('x86_64' 'aarch64')
url="https://github.com/rhgndf/rx888_stream"
license=('GPL3')
depends=('gcc-libs' 'libusb')
makedepends=('cargo' 'git')
provides=('rx888-stream')
conflicts=('rx888-stream')
source=(git+https://github.com/rhgndf/rx888_stream.git)
sha512sums=('SKIP')
pkgver() {
cd "$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
check() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
}
package() {
cd "$_pkgname"
install -Dm 755 "target/release/$_pkgname" -t "$pkgdir/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$_pkgname"
install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$_pkgname"
install -Dm 644 SDDC_FX3.img -t "$pkgdir/usr/share/$_pkgname"
}
# vim: ts=2 sw=2 et:
|