blob: 1d645e389bab0af3c9470bb57420b9cc5ffd9cdc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Stipe Kotarac <stipe@kotarac.net>
pkgname=schedtoold-git
pkgver=r1.b063cb7
pkgrel=1
pkgdesc='daemon for automatically adjusting process scheduling'
arch=('x86_64')
license=(GPL-2.0-only)
url='https://github.com/kotarac/schedtoold'
conflicts=('schedtoold')
depends=('schedtool')
makedepends=('cargo')
source=('schedtoold::git+https://github.com/kotarac/schedtoold.git#branch=main')
sha512sums=('SKIP')
pkgver() {
cd schedtoold/
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd schedtoold/
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd schedtoold/
cargo build --release --frozen
}
check() {
cd schedtoold/
cargo test --frozen
}
package() {
cd schedtoold/
install -D -m755 -s target/release/schedtoold $pkgdir/usr/bin/schedtoold
install -D -m644 schedtoold.service $pkgdir/usr/lib/systemd/system/schedtoold.service
install -D -m644 schedtoold.ron $pkgdir/etc/schedtoold.ron
}
|