blob: 7f775ed5404bd6dce57f7a301265d4fd2ed0482b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: whisky <archlinux.cle(at)gmail.com>
# Contributor: damir <damir@archlinux.org>
pkgname=scim-chewing
pkgver=0.5.1
pkgrel=4
pkgdesc='Traditional Chinese input method module for SCIM'
url='https://chewing.im/'
license=('GPL')
arch=('x86_64')
makedepends=('intltool')
depends=('scim' 'libchewing')
source=("$pkgname-$pkgver.tar.gz"::"https://github.com/chewing/scim-chewing/archive/v$pkgver.tar.gz")
sha256sums=('491b127784fa38734f3062fd57ea57e54f5f44d37b551ab25aab10c565cf6ebb')
prepare() {
cd ${pkgname}-${pkgver}
# ChangeLog is deprecated, but autotool expects one.
touch ChangeLog
autoreconf -vfi
intltoolize --force
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
}
|