blob: e0c0474d949d68fd4c8c865cd9f6049a4303a2c9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: nemanjan00 <nemanjan00+aur@gmail.com>
# Contributor: Filipe Laíns (FFY00) <filipe.lains@gmail.com>
# Contributor: Michal Krenek (Mikos) <m.krenek@gmail.com>
_pkgname=sdrangel
pkgname=$_pkgname-git
pkgver=7.22.2.r28.bd67d553e
pkgrel=1
pkgdesc='Qt5/OpenGL SDR and signal analyzer frontend.'
arch=('x86_64' 'i686' 'arm' 'armv6h' 'armv7h' 'aarch64')
url='https://github.com/f4exb/sdrangel'
license=('GPL3')
depends=('pkg-config' 'log4cpp' 'opencv' 'fftw'
'cm256cc' 'dsdcc' 'pulse-native-provider' 'lz4' 'nanomsg'
'qt5-base' 'qt5-multimedia' 'qt5-websockets' 'qt5-tools' 'qt5-charts' 'qt5-quickcontrols' 'qt5-quickcontrols2'
'qt5-serialport' 'qt5-declarative' 'qt5-location' 'qt5-speech' 'qt5-webengine' 'qt5-gamepad' 'qt5-svg' 'qt5-graphicaleffects')
# libsigmf requires the vendored version at https://github.com/f4exb/libsigmf/tree/new-namespaces, which isn't packaged yet
makedepends=('git' 'cmake' 'boost' 'doxygen' 'graphviz'
'ffmpeg' 'libdab' 'zlib' 'faad2' 'sgp4' 'aptdec' 'codec2'
'libmirisdr4' 'rtl-sdr' 'hackrf' 'libiio' 'limesuite' 'bladerf' 'libperseus-sdr' 'airspy' 'airspyhf' 'libxtrx' 'libuhd')
optdepends=('ffmpeg: DATV demodulator'
'libdab: DAB demodulator'
'zlib: DAB demodulator'
'faad2: DAB demodulator'
'sgp4: satellite tracker'
'aptdec: APT (weather satellite) decoder'
'codec2: FreeDV modulator/demodulator'
'libmirisdr4<2.0.0: SDRPlay support'
'rtl-sdr: RTLSDR support'
'hackrf: HackRF support'
'libiio: PlutoSDR support'
'limesuite: LimeSDR support'
'bladerf: BladeRF support'
'libperseus-sdr: Perseus SDR support'
'airspy: Airspy support'
'airspyhf: Airspy HF+ support'
'libxtrx: XTRX SDR support'
'libuhd: USRP support'
)
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("git+$url")
sha512sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --long --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g;s/\.rc./rc/g'
}
prepare() {
cd "$_pkgname"
}
build() {
# https://bugs.gentoo.org/704322
export CXXFLAGS="$CXXFLAGS -fpermissive"
cmake -B build -S "$_pkgname" \
-Wno-dev \
-DARCH_OPT="" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIBDSDCC_INCLUDE_DIR=/usr/include/dsdcc \
-DCM256CC_INCLUDE_DIR=/usr/include/cm256cc \
-DENABLE_CHANNELRX_DEMODDATV=OFF \
-DENABLE_CHANNELTX_MODDATV=OFF
make -C build
}
package() {
make -C build DESTDIR="$pkgdir" install
}
# vim: set noet ts=4
|