blob: 9d811de2db03d4402f115cc583c89806fc3eb901 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
pkgname=seabird
pkgver=0.5.1
pkgrel=1
pkgdesc='Native Kubernetes desktop client'
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url='https://getseabird.github.io'
license=('MPL-2.0')
depends=('gtksourceview5' 'libadwaita' 'vte4')
makedepends=('git' 'go' 'gobject-introspection')
options=('!emptydirs' '!lto')
source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/get${pkgname}/${pkgname}/archive/v${pkgver}.tar.gz"
"${pkgname}.desktop")
b2sums=('fec4ee50b8fa8a32194fb4ba1da8a9eefba04624a2368ea70a958bc13c3ddde2e3a87dd32cb9e9895a7d6497374d505cec064bd2125b143880a56bf5f56b9950'
'c8e36b0ac8dd4c1b1b47802926fa52ae03d699b245c78a7b47a6652dc62d9e943eecf94af2a901c9801de71d12d47adf14b024b9f7446e4cd3bef426ba47a119')
build() {
cd "${pkgname}-${pkgver}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
_LDFLAGS="-X main.version=${pkgver} -X main.branch=master -linkmode=external"
go generate ./...
go build -o seabird -ldflags="${_LDFLAGS}" .
}
package() {
# binary
install -D -m755 "${srcdir}/${pkgname}-${pkgver}/seabird" \
"${pkgdir}/usr/bin/seabird"
# icon
install -D -m644 "${srcdir}/${pkgname}-${pkgver}/internal/icon/${pkgname}.svg" \
"${pkgdir}/usr/share/icons/hicolor/scalable/apps/${pkgname}.svg"
# desktop file
install -D -m644 "${srcdir}/${pkgname}.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
# docs
install -D -m644 "${srcdir}/${pkgname}-${pkgver}/README.md" \
"${pkgdir}/usr/share/doc/${pkgname}/README.md"
}
|