blob: bcf5a0758bb41063a065c63739e1dfc664bb16a4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: David Runge <dvzrv@archlinux.org>
pkgname=sequoia-wot
pkgver=0.11.0
pkgrel=1
pkgdesc="An implementation of OpenPGP's web of trust"
arch=(x86_64)
url="https://gitlab.com/sequoia-pgp/sequoia-wot"
license=(LGPL-2.0-or-later)
groups=(sequoia)
depends=(
gcc-libs
glibc
gmp
nettle
openssl
sqlite
)
makedepends=(
cargo
clang
)
source=($url/-/archive/v$pkgver/$pkgname-v$pkgver.tar.gz)
sha512sums=('223493f3c87261fcf961a0c607b5dc155be2de082fa720451562a136aca46cce4216ff584a604409ab17c14c11351972be2509e8b0f3b3f7aa1e91ebf05d4977')
b2sums=('1e13a50fcec5e07c491d13a07d0830895a0dbf257b7d80ff2e09dca5405d6f315d7d5c488b7aa0f8d4808fc9f45cf806bb8f08a15e2006f273bfd4baae997e32')
prepare() {
cd $pkgname-v$pkgver
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd $pkgname-v$pkgver
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features --features sequoia-openpgp/crypto-nettle
}
check() {
cd $pkgname-v$pkgver
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features --features sequoia-openpgp/crypto-nettle
}
package() {
cd $pkgname-v$pkgver
install -vDm 755 target/release/sq-wot -t "$pkgdir/usr/bin/"
install -vDm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
install -vDm 644 target/release/build/${pkgname}*/out/sq-wot.bash "$pkgdir/usr/share/bash-completion/completions/sq-wot"
install -vDm 644 target/release/build/${pkgname}*/out/sq-wot.fish -t "$pkgdir/usr/share/fish/completions/"
install -vDm 644 target/release/build/${pkgname}*/out/_sq-wot -t "$pkgdir/usr/share/zsh/site-functions/"
}
|