blob: 1663a0aefb208385fb5e98ad955ea463bb989cf4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Louis Solofrizzo <louis@ne02ptzero.me>
_pkgname=shayla
pkgname="${_pkgname}-git"
pkgver=1.1.r0.g28bb961
pkgrel=1
pkgdesc="A fast and simple static site generator"
arch=("i686" "x86_64" "arm" "armv6h" "armv7h" "aarch64")
url="https://git.sr.ht/~ne02ptzero/shayla"
license=("GPL3")
makedepends=("cmake" "git" "gcc")
provides=("shayla")
conflicts=("shayla")
source=("${_pkgname}::git+${url}")
md5sums=("SKIP")
pkgver() {
git -C "${_pkgname}" describe --long --tags | sed "s/-/.r/;s/-/./g"
}
prepare() {
git -C "${_pkgname}" submodule update --init --recursive
mkdir -p "${_pkgname}/build"
}
build() {
cd "${_pkgname}/build" || exit 1
cmake -DCMAKE_INSTALL_PREFIX=/usr ..
cmake --build .
}
package() {
cmake --build "${_pkgname}/build" --target install -- DESTDIR="${pkgdir}"
install -Dm644 "${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}
|