blob: eee7431413a1fa15e3c0542ee4301aa3af6620bb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: nic96 <jeromyreimer at gmail dot com>
PKGEXT=.pkg.tar
pkgname=shotcut-bin
pkgver=181008
pkgrel=1
pkgdesc="A free, open source, cross-platform video editor."
arch=(x86_64)
url="https://www.shotcut.org/"
license=('GPL3')
depends=('jack' 'libexif' 'desktop-file-utils' 'gstreamer' 'libxslt' 'libwrap')
provides=('shotcut')
install="$pkgname.install"
source=("https://github.com/mltframework/shotcut/releases/download/v${pkgver::2}.${pkgver:2:2}.${pkgver:4:2}/shotcut-linux-x86${CARCH/*86}-$pkgver.tar.bz2"
"shotcut.png")
md5sums=('f3f0d128d4c2bda37d0deb613e8c046a' '457bc6ae5a299dee017521ec058e833b')
prepare() {
cd Shotcut
# fix and modify desktop file
sed -i '1d;/Exec/s/sh.*/shotcut-bin/' Shotcut.desktop
sed -i 's/Icon=applications-multimedia/Icon=shotcut/g' Shotcut.desktop
echo "Categories=Qt;AudioVideo;AudioVideoEditing;" >> Shotcut.desktop
}
package() {
cd Shotcut
# bundle
install -d "$pkgdir/opt/shotcut"
cp -a Shotcut.app/* "$pkgdir/opt/shotcut"
# desktop file
install -Dm644 Shotcut.desktop "$pkgdir/usr/share/applications/$pkgname.desktop"
# shotcut icon
install -Dm644 "$srcdir/shotcut.png" "$pkgdir/usr/share/pixmaps/shotcut.png"
# launcher
install -d "$pkgdir/usr/bin"
ln -s /opt/shotcut/shotcut "$pkgdir/usr/bin/$pkgname"
}
|