blob: 8ec5ddc3a9c98ec42d91434ca6750903167fd76f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# Maintainer: Eduard Tolosa <edu4rdshl@protonmail.com>
# PKGBUILD modified from kpcyrd <kpcyrd[at]archlinux[dot]org>
# Contributor: Jean Lucas <jean@4ray.co>
# This package is just an adaptation of the signal-desktop package
# that is in the official repos in order to provide a beta version
# of signal that does not use precompiled binaries.
pkgname=signal-desktop-beta
_pkgname=Signal-Desktop
_sticker_creator="sticker-creator"
_desktop_file='signalbeta.desktop'
pkgver=7.51.0beta3
pkgrel=1
pkgdesc='Signal Private Messenger for Linux - Beta version.'
license=('GPL3')
conflicts=('signal-desktop-beta-bin')
arch=('x86_64' 'aarch64')
url="https://signal.org"
depends=(
'gcc-libs'
'glibc'
'gtk3'
'hicolor-icon-theme'
'libasound.so'
'libatk-bridge-2.0.so'
'libcairo.so'
'libcups'
'libdbus-1.so'
'libdrm'
'libexpat.so'
'libgio-2.0.so'
'libpango-1.0.so'
'libx11'
'libxcb'
'libxcomposite'
'libxdamage'
'libxext'
'libxfixes'
'libxkbcommon.so'
'libxrandr'
'mesa'
'nspr'
'nss'
)
# We need libxcrypt-compat for it to build: https://github.com/electron-userland/electron-builder-binaries/issues/47
makedepends=(
'git'
'git-lfs'
'libxcrypt-compat'
'node-gyp'
'nodejs'
'python'
'pnpm'
)
optdepends=('xdg-desktop-portal: Screensharing with Wayland')
makedepends_aarch64=('fpm')
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/signalapp/${_pkgname}/archive/v${pkgver//beta*}-beta.${pkgver##*beta}.tar.gz"
"${_desktop_file}"
)
sha512sums=('b9331e6fbc96670e0a0be35697adbdb0661a81985ae9b34908eb7c69b0865cb693ef7f6294382d19dff82cd9cc2989b3bdeb9155ebb257f7a15a7256211a8fa5'
'5ae001faedff440776f4a62235c294454a951f4cc412665a21cd958bdf4a0223c89f741f2786d93727c7acf49a8a98d75156c6e14ba1f01da261fba373ef675a')
prepare() {
cd "${_pkgname}-${pkgver//beta*}-beta.${pkgver##*beta}"
# git-lfs hook needs to be installed for one of the dependencies
git lfs install
# Allow higher Node versions
sed 's#"node": "#&>=#' -i package.json
# Electron from 34.4.x/35.x onwards, creates strange artifacts on ArchLinux, lets downgrande to electron 34.3.x
sed -i 's/"electron": *"[^"]*"/"electron": "34.3.4"/g' package.json
# Install dependencies for sticker-creator
pnpm --prefix ./sticker-creator/ install
# Install dependencies for signal-desktop
pnpm install
}
build() {
cd "${_pkgname}-${pkgver//beta*}-beta.${pkgver##*beta}"
# Build the sticker creator
USE_SYSTEM_FPM=$([ $(uname -m) == "aarch64" ] && echo true || echo false) bash -c 'pnpm --prefix ./sticker-creator/ run build'
# Build Signal Desktop Beta
pnpm run generate
pnpm run prepare-beta-build
USE_SYSTEM_FPM=$([ $(uname -m) == "aarch64" ] && echo true || echo false) bash -c 'pnpm run build:esbuild:prod && pnpm run build:release -- --linux dir'
}
package() {
cd "${_pkgname}-${pkgver//beta*}-beta.${pkgver##*beta}"
install -d "${pkgdir}/usr/"{lib,bin}
case "${CARCH}" in
"aarch64") folder="linux-arm64-unpacked" ;;
*) folder="linux-unpacked" ;;
esac
cp -a release/${folder} "${pkgdir}/usr/lib/${pkgname}"
ln -s "/usr/lib/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/"
chmod u+s "${pkgdir}/usr/lib/${pkgname}/chrome-sandbox"
install -Dm 644 "../${_desktop_file}" -t "${pkgdir}/usr/share/applications"
for i in 16 24 32 48 64 128 256 512 1024; do
install -Dm 644 "build/icons/png/${i}x${i}.png" \
"${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${pkgname}.png"
done
}
|