blob: 931edabc67214c0c97c79a62b136055c3043b5d6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Janek Thomaschewski <janek@jbbr.net>
# Maintainer: Stephan Springer <buzo+arch@Lini.de>
pkgname=signal-desktop-bin
pkgver=1.24.1
pkgrel=1
pkgdesc='Private messaging from your desktop'
arch=('x86_64')
url='https://github.com/signalapp/Signal-Desktop'
license=('GPL3')
provides=('signal-desktop')
conflicts=('signal')
options=('!strip')
depends=('gconf' 'gtk3' 'libnotify' 'nss' 'xdg-utils' 'libxss')
source=("https://updates.signal.org/desktop/apt/pool/main/s/signal-desktop/signal-desktop_${pkgver}_amd64.deb")
sha256sums=('392a8ce97b8a41ee9f55d39b07ce7a6c7b591c5cc607d5b22d323ed849e7b9a4')
package() {
# extract package data
tar xf data.tar.xz -C "${pkgdir}"
# fix permissions in 1.9.0+ (Some directories have now 775; changing them back to 755)
find "${pkgdir}" -type d -not -perm 755 -exec chmod 755 {} \;
# install symbolic link in /usr/bin
install -d -m755 "${pkgdir}/usr/bin"
ln -s /opt/Signal/signal-desktop "${pkgdir}/usr/bin"
# second desktop entry for starting in tray only
sed -e 's,^\(Name=.*\),\1 (Start in Tray),' -e 's,^\(Exec=.*\)%U,\1--start-in-tray %U,' \
"${pkgdir}"/usr/share/applications/signal-desktop.desktop \
> "${pkgdir}"/usr/share/applications/signal-desktop-tray.desktop
}
|