PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: k1f0 <archlinux at k1f0.mozmail.com>

pkgname=signalbackup-tools-git
pkgver=20241106.1.r0.g242c983
pkgrel=1
pkgdesc="Tool to work with Signal Backup files"
arch=('x86_64')
url="https://github.com/bepaald/signalbackup-tools"
license=('GPL3')
depends=('openssl' 'sqlite' 'dbus')
makedepends=('git' 'pkgconfig' 'cmake')
provides=("signalbackup-tools")
conflicts=()
source=("git+https://github.com/bepaald/${pkgname%-git}.git")
md5sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname%-git}"
	printf "%s" "$(git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g')"
}

build() {
	cd "${srcdir}/${pkgname%-git}"
	cmake -B output -DCMAKE_BUILD_TYPE=Release
	cmake --build output -j $(nproc)
}

package() {
	cd "${srcdir}/${pkgname%-git}"
	install -Dm755 "output/${pkgname%-git}" "${pkgdir}/usr/bin/${pkgname%-git}"
	install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname%-git}/README"
	install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname%-git}/LICENSE"
}