summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 8e6c414034a2ba6f98133020eab3020b46ccbb02 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Maintainer:  Caleb Maclennan <caleb@alerque.com>
# Contributor: Adrián Pérez de Castro <aperez@igalia.com>

pkgname=sile-git
pkgdesc='Modern typesetting system inspired by TeX'
pkgver=0.9.5.1.r321.g26c0213
_branch='testing'
pkgrel=2
arch=(any)
url='http://www.sile-typesetter.org'
license=('MIT')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
_lua_deps=('bit32' 'luaepnf' 'lpeg' 'cassowary>=2.2' 'linenoise' 'zlib' 'cliargs'
           'luaepnf' 'filesystem' 'repl' 'sec' 'socket' 'penlight' 'stdlib'
           'vstruct')
depends=('fontconfig'
         'harfbuzz>=1.4.2'
         "${_lua_deps[@]/#/lua-}"
         'icu'
         'ttf-gentium-plus')
optmakedepents=('luajit')
makedepends=('git'
             'lua-busted'
             'lua-luacov=0.8'
             'lua-luacov-coveralls')
source=("git://github.com/alerque/${pkgname%-git}.git#branch=$_branch")
sha512sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare () {
    cd "$srcdir/${pkgname%-git}"
    ./bootstrap.sh
}

build () {
    cd "$srcdir/${pkgname%-git}"
    ./configure --prefix=/usr --with-system-luarocks
    make
}

package () {
    cd "$srcdir/${pkgname%-git}"
    make install DESTDIR="$pkgdir/"
}