blob: 9302e48ff7355597660cac00a8a9375d40216c49 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Chris Speck <chris.speck(at)annalise(dot)ai>
pkgname=slack-desktop-wayland
_original_pkgname=slack-desktop
pkgver=4.36.134
pkgrel=3
pkgdesc="Slack Desktop (Beta) for Linux with Wayland Support"
arch=('x86_64')
url="https://slack.com/downloads"
license=('custom')
depends=('gtk3' 'libsecret' 'libxss' 'nss' 'pipewire' 'xdg-utils' 'xdg-desktop-portal')
optdepends=('libappindicator-gtk3: Systray indicator support'
'org.freedesktop.secrets: Keyring password store support'
'xdg-desktop-portal-gnome: xdg-desktop-portal support for GNOME'
'xdg-desktop-portal-gtk: xdg-desktop-portal support for GNOME and GTK'
'xdg-desktop-portal-kde: xdg-desktop-portal support for KDE'
'xdg-desktop-portal-lxqt: xdg-desktop-portal support for LXQt'
'xdg-desktop-portal-wlr: xdg-desktop-portal support for wlroots-based Wayland compositors'
)
source=(
"https://downloads.slack-edge.com/releases/linux/${pkgver}/prod/x64/${_original_pkgname}-${pkgver}-amd64.deb"
"${_original_pkgname}.patch"
)
noextract=("${_original_pkgname}-${pkgver}-amd64.deb")
b2sums=('d24e5ad17c4a340bf57c341e67f31d515cc516277fab021e9a7dd2deea02464230aacb72dff56af971df2f5d08ba2881694a9faa559a70bb53ad7d3edb944a1f'
'6694368fd7fb8712b41180ca60380567cf49c4632db8df3599186f1cd8c780ba67acfa90e2b5a629915744c4163cbb5a36ff0cd1fefc8789651180a20336eca9')
provides=('slack-desktop')
conflicts=('slack-desktop' 'slack-electron')
package() {
bsdtar -O -xf "slack-desktop-${pkgver}"*.deb data.tar.xz | bsdtar -C "${pkgdir}" -xJf -
# Fix hardcoded icon path in .desktop file
patch -d "${pkgdir}" -p1 <"${_original_pkgname}".patch
# Permission fix
find "${pkgdir}" -type d -exec chmod 755 {} +
# Remove all unnecessary stuff
rm -rf "${pkgdir}/etc"
rm -rf "${pkgdir}/usr/lib/slack/src"
rm -rf "${pkgdir}/usr/share/lintian"
rm -rf "${pkgdir}/usr/share/doc"
# Move license
install -dm755 "${pkgdir}/usr/share/licenses/${_original_pkgname}"
mv "${pkgdir}/usr/lib/slack/LICENSE" "${pkgdir}/usr/share/licenses/${_original_pkgname}"
ln -s "/usr/share/licenses/${_original_pkgname}/LICENSE" "${pkgdir}/usr/lib/slack/LICENSE"
# patch the asar file to fix/enable pipewire
# see https://github.com/flathub/com.slack.Slack/issues/101#issuecomment-1807073763
sed -i -e 's/,"WebRTCPipeWireCapturer"/,"_ebRTCPipeWireCapturer"/' "${pkgdir}/usr/lib/slack/resources/app.asar"
}
|