PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: SteamedFish <steamedfish@hotmail.com>
# Contributor: Joshua Rubin <me at jawa dot dev>
pkgname=soapysdrplay3-luarvique-git
pkgver=r157.8328621
pkgrel=1
pkgdesc="Soapy SDR module for SDRPlay APIv3"
arch=('i686' 'x86_64' 'aarch64')
url="http://www.sdrplay.com"
license=('MIT')
depends=('soapysdr' 'libsdrplay' 'gcc-libs')
provides=('soapysdrplay3' 'soapysdrplay')
conflicts=('soapysdrplay3' 'soapysdrplay3-git')
makedepends=('cmake' 'git')
install=${pkgname}.install
source=("$pkgname::git+https://github.com/luarvique/SoapySDRPlay3.git")
md5sums=('SKIP')

pkgver() {
	cd "$pkgname"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cmake -B build \
	    -S "$srcdir/$pkgname" \
	    -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
	    -DCMAKE_INSTALL_PREFIX=/usr
	make -C build
}

package() {
	make -C build DESTDIR="$pkgdir/" install
	install -D -m644 $srcdir/$pkgname/LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}