blob: 5bb109c10f3e20ea3109e73e4bc4b5f31fd49194 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
pkgname=sopel-git
pkgver=6.5.0.r0.gf6315f7
pkgrel=1
pkgdesc="An easy-to-use and highly extensible IRC Bot framework (Formerly Willie)"
arch=('any')
license=('custom:EFL')
url='http://sopel.chat'
depends=('python-setuptools' 'sqlite' 'python-xmltodict' 'python-pytz' 'python-praw'
'python-pyenchant' 'python-pygeoip')
makedepends=('git' 'python-sphinx')
checkdepends=('python-pytest' 'ipython')
conflicts=('sopel')
provides=('sopel')
backup=('etc/sopel.cfg')
source=("git+https://github.com/sopel-irc/sopel.git"
"sopel.cfg")
md5sums=('SKIP'
'1363307140463925249767d6b0e71341')
install=install
pkgver() {
cd $srcdir/sopel
git describe --long --tags| sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
sed -i 's/requests>.*/requests/' sopel/requirements.txt
export LC_CTYPE=en_US.UTF-8
}
build() {
cd sopel
python setup.py build
make -C docs man
}
check() {
cd sopel
py.test --ignore=sopel.py --ignore=build/
}
package() {
cd sopel
python setup.py install --root="$pkgdir" --optimize=1
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 ../sopel.cfg "$pkgdir/etc/sopel.cfg"
install -Dm644 contrib/sopel.service "$pkgdir/usr/lib/systemd/system/sopel.service"
install -Dm644 contrib/sopel.conf "$pkgdir/usr/lib/tmpfiles.d/sopel.conf"
install -Dm644 docs/build/man/sopel.1 "$pkgdir/usr/share/man/man1/sopel.1"
install -dm755 $pkgdir/var/lib/sopel
install -dm755 $pkgdir/var/log/sopel
}
|