blob: 4cad6a62c0d624c67cdcc14dcc9e93240af94d36 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer:
# Contributor: FabioLolix
# Contributor: Simon Hauser <Simon-Hauser@outlook.de>
# Contributor: Jean Lucas <jean@4ray.co>
pkgname=spotify-tui-git
pkgver=0.25.0.r15.gc4dcf6b
pkgrel=1
pkgdesc="Spotify client for the terminal written in Rust"
arch=(x86_64)
url="https://github.com/Rigellute/spotify-tui"
license=(MIT)
depends=(gcc-libs openssl)
makedepends=(git cargo)
provides=(spotify-tui)
conflicts=(spotify-tui)
source=("git+https://github.com/Rigellute/spotify-tui.git")
sha512sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${pkgname%-git}"
cargo build --locked --release
}
package() {
cd "${pkgname%-git}"
install -D target/release/spt -t "$pkgdir/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
|