PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Maintainer: Aira Hinano <hinanoaira at hinasense dot jp>
# Co-Maintainer: kazu0617 <archlinux at kazu0617 dot net>
# Contributor: Xesxen

pkgname=steamlink
pkgver=1.3.24.301
pkgrel=1
pkgdesc="Steam Link client"
arch=('x86_64')
url="https://store.steampowered.com/remoteplay#anywhere"
license=('LicenseRef-Steam')
provides=("steamlink=${pkgver}")
conflicts=('steamlink-bin')
replaces=('steamlink-bin')
depends=(
	'bzip2'
	'dbus'
	'ffmpeg'
	'freetype2'
	libicu{data,i18n,uc}.so=77
	'libglvnd'
	'opus'
	'sdl3'
	'systemd-libs'
	'zlib'
  'libjpeg6-turbo'
)
makedepends=('ostree' 'fakeroot')
options=(!debug !lto)
source=(
    "flathub.gpg"
    "steamlink.sh"
)

_ostree_commit="85941404406e12178a2493d2ae841e3c88ec5670d2790d089b36f6d20282e5f8"
sha256sums=('8bdc20abc4e19c0796460beb5bfe0e7aa4138716999e19c6f2dbdd78cc41aeaa'
            '4d5bd2835b7ccf71e53e0f6f2c4bc9a3fe2477345cb51517f05b019dd63b8fe8')

prepare() {
  mkdir -p ostree
  ostree init --repo ./ostree
  ostree remote add --gpg-import=flathub.gpg --repo ./ostree flathub https://dl.flathub.org/repo/ || true
  fakeroot ostree pull --repo ./ostree flathub app/com.valvesoftware.SteamLink/x86_64/stable@$_ostree_commit
}

build() {
  ostree export --repo ./ostree flathub:$_ostree_commit --subpath files > steamlink.tar
}

package() {
  # Install main application files
  install -dm755 "$pkgdir/opt/steamlink"
  tar -xf ./steamlink.tar -C "$pkgdir/opt/steamlink" bin/ lib/ README.txt
  
  # Install wrapper script
  install -Dm755 "$srcdir/steamlink.sh" "$pkgdir/usr/bin/steamlink"

  # Install desktop entry and icons
  tar -xf ./steamlink.tar -C "$pkgdir/usr" share/applications/ share/icons/
  sed -i 's/\/app\/bin/\/usr\/bin/g' "$pkgdir/usr/share/applications/com.valvesoftware.SteamLink.desktop"

  # Install license files
  install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
  tar -xf ./steamlink.tar -C "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt ThirdPartyLegalNotices.css ThirdPartyLegalNotices.html
}