PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: 
# Co-Maintainer: Alan Jenkins <alan.james.jenkins@gmail.com>
# Contributor: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=steamtinkerlaunch-git
pkgver=11.11.r44.g448dc51
pkgrel=1
pkgdesc="Wrapper script for Steam custom launch options"
arch=('any')
url="https://github.com/sonic2kk/steamtinkerlaunch"
license=('GPL3')
depends=('bash' 'procps-ng' 'unzip' 'xxd' 'wget' 'xdotool' 'xorg-xprop' 'xorg-xrandr' 'xorg-xwininfo' 'yad')
makedepends=('git')
optdepends=(
	'strace: write a strace log of the launched game'
	'gamemode: for using GameMode per game'
	'mangohud: for using MangoHUD per game'
	'vkbasalt: for using vkBasalt per game'
	'winetricks: winetricks support'
	'vr-video-player: for playing regular games side-by-side in VR'
	'nyrna: for using Nyrna per game'
	'replay-sorcery: for using Replay-Sorcery per game'
	'net-tools: for optional network monitoring'
	'boxtron: for optional Boxtron support'
	'scummvm: for optional ScummVM support via Roberta'
	'wine: for optional wine support'
	'gameconqueror: for optional cheating'
	'gamescope: for optional GameScope support'
	'libnotify: for optional Notifier'
	'innoextract: optional for extracting the Cheat Engine setup archive'
	'usbutils: optional for a quick VR HMD presence check'
	'jq: optional for extracting game names from the steam api'
	'rsync: optional for backing up steamuser files from proton games'
	'imagemagick: optional to scale a custom installed game header picture and for converting game icons'
	'p7zip: optional for extracting SpecialK archives'
	'pev: optional for extracting data from the game exe'
	'gdb: optional for starting the game under the debugger gdb'
	'xdg-utils: optional for opening game paths'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/sonic2kk/steamtinkerlaunch.git')
sha1sums=('SKIP')

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
	cd "$srcdir/${pkgname%-git}"
	install -Dm755 "${pkgname%-git}" -t "$pkgdir/usr/bin"

  install -d "$pkgdir/usr/share/${pkgname%-git}"
  cp -r collections eval guicfgs lang misc "$pkgdir/usr/share/${pkgname%-git}"

  install -Dm644 README.md -t "$pkgdir/usr/share/doc/${pkgname%-git}"
  install -Dm644 "misc/${pkgname%-git}.desktop" -t "$pkgdir/usr/share/applications"
  install -Dm644 "misc/${pkgname%-git}.svg" -t "$pkgdir/usr/share/icons/hicolor/scalable/apps"
}