PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

# Maintainer: Frederik “Freso” S. Olesen <archlinux@freso.dk>
_pkgname=SteamTokenDumper
pkgname=${_pkgname,,}-bin
pkgver=2024.10.12
pkgrel=1
pkgdesc='Steam token dumper for SteamDB'
arch=('x86_64' 'x86_64_v3')
url='https://steamdb.info/tokendumper/'
license=('MIT')
backup=("opt/${pkgname%-bin}/$_pkgname.config.ini")
makedepends=('coreutils')
provides=("${pkgname%-bin}")
conflicts=("${pkgname%-bin}")
options=(!strip)
source=("${pkgname%-bin}.sh")
source_x86_64=("${_pkgname}-${pkgver}-linux-x64.tar.gz::https://github.com/SteamDatabase/${_pkgname}/releases/download/${pkgver}/${_pkgname}-linux-x64.tar.gz")
source_x86_64_v3=("${source_x86_64[@]}")
sha256sums=('b9e3c64ecfc793401d4397a9fb789da87fe4b49dcd30fe97855ac0aa4b91cabd')
sha256sums_x86_64=('9a7abaa469088217292ec2346cd999464f48f774354f7094708b314f3a12d346')
sha256sums_x86_64_v3=('9a7abaa469088217292ec2346cd999464f48f774354f7094708b314f3a12d346')

package(){
  depends=('libz.so=1-64' 'glibc' 'gcc-libs' 'sh')  # TODO: Depend on .so files instead of packages
  optdepends=('unionfs-fuse: mounting user writable settings etc. directory')

  install -Dm755 SteamTokenDumper "$pkgdir"/opt/${pkgname%-bin}/SteamTokenDumper
  install -Dm644 SteamTokenDumper.config.ini "$pkgdir"/opt/${pkgname%-bin}/SteamTokenDumper.config.ini
  install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/${pkgname%-bin}/LICENSE.txt
  install -Dm755 "${pkgname%-bin}.sh" "$pkgdir"/usr/bin/${pkgname%-bin}
}