blob: 98e6e5efc109980fc09f0c09ddd82300f179253d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: devome <evinedeng@hotmail.com>
_reponame=Stirling-PDF
_pkgname="${_reponame,,}"
pkgname="${_pkgname}-bin"
pkgver=2.4.5
pkgrel=1
pkgdesc="Locally hosted web application that allows you to perform various operations on PDF files"
arch=("any")
url="https://github.com/Stirling-Tools/${_reponame}"
provides=("${_pkgname}")
conflicts=("${_pkgname}")
license=("MIT")
backup=("etc/${_pkgname}/${_pkgname}.env")
depends=(
"fontconfig"
"ghostscript"
"java-runtime-headless>=21"
"libreoffice"
"ocrmypdf"
"poppler"
"python-opencv"
"python-pdf2image"
"python-pillow"
"python-unoserver"
"python-weasyprint"
"tesseract-data-eng"
"unpaper"
)
optdepends=("calibre: for ebook conversion"
"jbig2enc: for certain OCR functionality"
"tesseract-data-chi_sim: Chinese Simplified language OCR"
"tesseract-data-deu: German language OCR"
"tesseract-data-fra: French language OCR"
"tesseract-data-por: Portuguese language OCR"
"noto-fonts: google noto ttf fonts"
"noto-fonts-cjk: google noto Chinese/Japanese/Korean fonts"
"noto-fonts-extra: google noto ttf fonts additional variants"
"terminus-font: monospace bitmap font"
"ttf-dejavu: based on the Bitstream Vera Fonts with a wider range of characters"
"ttf-liberation: which aims at metric compatibility with Arial, Times New Roman, and Courier New"
"ttf-libertinus: extended math fonts support"
"ttf-ms-win11-auto: Microsoft windows 11 fonts"
"ttf-ms-win11-auto-zh_cn: Microsoft windows 11 Chinese Simplified fonts"
"ttf-wps-fonts: WPS office fonts")
source=("${_pkgname}-${pkgver}.jar::${url}/releases/download/v${pkgver}/${_reponame}-with-login.jar"
"${_pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
"${_pkgname}.env"
"${_pkgname}.service"
"${_pkgname}.sh"
"${_pkgname}.sysusers"
"${_pkgname}.tmpfiles")
sha256sums=('181b754ea842514fca3d95f802e2d93e67448a3f774e343b36b2c2fbb267d4d3'
'c9141913d9bddf7b6faed1dfcb079452dafe99ef5475a3a64f0fd5651708df80'
'd1601a440ef408a93edbc8d280bd0747712a54cc461fe10a34f1c6aaf52ff84e'
'd0ef8935451c1ef75e08b4b977289ff84892a3b12820d6e212db1c19dd6eddc9'
'67654b2198898e23d0cf35829e83cc0585b7335b8bd7fcd9da0e4a2ce90082d6'
'efdf233d59cf82bc331e3ea85e912e7f534ed0d821674e232e3fc827f699ef43'
'554fbc114c32f4b81fe3b8199e936881e26b5649098c495acfd4cd77eefd2612')
noextract=("${_pkgname}-${pkgver}.jar")
package() {
install -Dm644 "${_pkgname}-${pkgver}.jar" "${pkgdir}/usr/share/java/${_pkgname}.jar"
install -Dm644 "${_pkgname}.env" "${pkgdir}/etc/${_pkgname}/${_pkgname}.env"
install -Dm644 "${_pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${_pkgname}.service"
install -Dm755 "${_pkgname}.sh" "${pkgdir}/usr/bin/${_pkgname}"
install -Dm644 "${_pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${_pkgname}.conf"
install -Dm644 "${_pkgname}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${_pkgname}.conf"
cd "${_reponame}-${pkgver}"
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${_pkgname}"
install -Dm644 *.md -t "${pkgdir}/usr/share/doc/${_pkgname}"
cd "app/core/src/main/resources"
install -Dm644 static/fonts/*.ttf -t "${pkgdir}/usr/share/fonts/${_pkgname}"
}
|