summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 8f507126203a575f6d39ecc7e65c5943600cabf1 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Balló György <ballogyor+arch at gmail dot com>

pkgname=svgvi
pkgver=2.0.2
pkgrel=1
pkgdesc="SVG Text Editor and Viewer"
arch=(x86_64)
url="https://gitlab.com/gsvg/svgvi"
license=(GPL-3.0-only)
depends=(gsvgtk gtksourceview5)
makedepends=(git meson vala gresg)
source=("git+https://gitlab.com/gsvg/svgvi.git#tag=${pkgver}")
sha256sums=('31a67716a6324717eb92486291b59f9ae79a68622c8abd6a4a9a731a4dfc7afe')

build() {
  export CFLAGS+=" -Wno-implicit-function-declaration"
  export CXXFLAGS+=" -Wno-implicit-function-declaration"

  arch-meson svgvi build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  DESTDIR="${pkgdir}" meson install -C build
  ln -s /usr/bin/mx.pwmc.Svgvi "${pkgdir}/usr/bin/svgvi"
}