summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: afaeedf936cb4fceb8371a56d2bba83a7bb7bdbc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
# Maintainer : Daniel Bermond <dbermond@archlinux.org>
# Contributor: Thomas Schneider <maxmusterm@gmail.com>

pkgname=svt-vp9-git
pkgver=0.3.0.r3.g10910b7
pkgrel=1
pkgdesc='Scalable Video Technology VP9 encoder (git version)'
arch=('x86_64')
url='https://github.com/OpenVisualCloud/SVT-VP9/'
license=('BSD')
depends=('glibc')
makedepends=('git' 'cmake' 'yasm')
provides=('svt-vp9')
conflicts=('svt-vp9')
source=('git+https://github.com/OpenVisualCloud/SVT-VP9.git')
sha256sums=('SKIP')

pkgver() {
    git -C SVT-VP9 describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

build() {
    cmake -B build -S SVT-VP9 \
        -DCMAKE_BUILD_TYPE:STRING='None' \
        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
        -Wno-dev
    make -C build
}

package() {
    make -C build DESTDIR="$pkgdir" install
    install -D -m644 SVT-VP9/LICENSE.md -t "$pkgdir/usr/share/licenses/${pkgname}"
}