summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: a9ea4e3c2adc6a793f3d8a0044dc5988126df5ba (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
# Maintainer: Vyacheslav Konovalov <🦀vk@protonmail.com>

pkgname=swarm-bee-bin
pkgver=0.6.2
pkgrel=1
pkgdesc='Swarm client implemented in Go, basic building block for Swarm Network'
arch=('x86_64')
url='https://swarm.ethereum.org/'
license=('BSD-3-Clause')
depends=('bash')
optdepends=('bee-clef: external signer for bee')
backup=('etc/bee/bee.yaml')
source=(
    "https://github.com/ethersphere/bee/releases/download/v$pkgver/bee_${pkgver}_amd64.deb"
    'https://raw.githubusercontent.com/ethersphere/bee/master/LICENSE'
)
sha512sums=(
    'c29b47d48955a9a70fe765691e5d864c162b852b24d81c780149dd122d01ce232d7de3d80c41427b96627ea7cf33223da9258c3bda3d706abe28cbcd7ef74ee1'
    '63cb4eacde7f6f664dc42f07fd2b46dab7c72a621b57ef60481f0f3484445073c8c11310c38a6b85c801be64bc38a6e4c38186ffe0b2abd188d2a6ec6e03a9ab'
)
install='bee.install'

prepare() {
    bsdtar -xf data.tar.gz
}

package() {
    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/bee"
    install -Dm644 etc/default/bee -t "$pkgdir/etc/default"
    install -Dm644 etc/bee/bee.yaml -t "$pkgdir/etc/bee"
    install -Dm644 lib/systemd/system/bee.service -t "$pkgdir/usr/lib/systemd/system"
    install -Dm755 usr/bin/bee{,-get-addr} -t "$pkgdir/usr/bin"
}