summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 642f150fdfe91e7b0a2c62549db6cafcd274e784 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
# Contributor: orbisvicis <''.join(chr(ord(c)-1) for c in "pscjtwjdjtAhnbjm/dpn")>
# Contributor: Ray Rashif <rayrashif@gmail.com>

_pkgname=swh-lv2
pkgname="${_pkgname}-git"
pkgver=1.0.15.r43.5098e09
pkgrel=1
pkgdesc="Experimental port of Steve Harris' LADSPA plugins to LV2 format"
arch=('i686' 'x86_64')
url="http://plugin.org.uk/"
license=("GPL3")
groups=('lv2-plugins')
depends=('fftw' 'lv2')
makedepends=('git' 'libxslt')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+https://github.com/swh/lv2.git")
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}"

  ver=$(grep ^VERSION Makefile | sed 's/VERSION = //')
  echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
  cd "${srcdir}/${_pkgname}"

  make
}

package() {
  cd "${srcdir}/${_pkgname}"

  make INSTALL_DIR="${pkgdir}/usr/lib/lv2" install-system
}

# vim:set ts=2 sw=2 et: