blob: a662b648a9fb08c7db225c2c78a376a8ffad343c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Ebrahim Azarisooreh <ebrahim.azarisooreh@gmail.com>
# Contributor: Nikolaos Bezirgiannis <bezeria@gmail.com>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jachym Barvinek <jachymb@gmail.com>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: John Proctor <jproctor@prium.net>
# Contributor: Juergen Hoetzel <juergen@archlinux.org>
pkgname=swi-prolog-devel
pkgver=9.3.3
pkgrel=1
pkgdesc='Prolog environment (development version)'
arch=('x86_64' 'i686')
url='https://www.swi-prolog.org/'
license=(GPL LGPL)
depends=('gmp' 'readline' 'openssl' 'libarchive' 'libyaml')
makedepends=(cmake jdk-openjdk junit libjpeg libxft libxinerama libxpm ninja unixodbc)
optdepends=('unixodbc: for using the odbc4pl library'
'uuid: for using the uuid library'
'libjpeg: for using the pl2xpce library'
'libxpm: for using the pl2xpce library'
'libxinerama: for using the pl2xpce library'
'libxft: for using the pl2xpce library'
'jdk-openjdk: for using Prolog from Java'
'java-runtime: for using Prolog from Java')
source=("https://www.swi-prolog.org/download/devel/src/swipl-$pkgver.tar.gz")
sha256sums=('db8453356811edbb4c2130d52617d327a4b4e322e2941dd4d52b5751d03e3946')
provides=('swi-prolog')
conflicts=('swi-prolog')
build() {
mkdir -p build
cd build
cmake ../swipl-$pkgver \
-DCMAKE_BUILD_TYPE=PGO \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_C_FLAGS="$CFLAGS -fPIC -ffile-prefix-map=$PWD= -w" \
-DLIBEDIT_LIBRARIES=/usr/lib/libedit.so.0 \
-DLIBEDIT_INCLUDE_DIR=/usr/include \
-DUSE_TCMALLOC=OFF \
-G Ninja
#../swipl-$pkgver/scripts/pgo-compile.sh
ninja
}
check() {
cd build
# the prolog_in_java test fails
ctest -j 8 || true
}
package() {
DESTDIR="$pkgdir" ninja -C build install
}
# getver: www.swi-prolog.org/download/devel
# vim: ts=2 sw=2 et:
|