blob: d9373c21c06b7979e909ca4221a88c1d4eeaabab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Ashley Towns <mail(at)ashleytowns(dot)id(dot)au>
_version=2.2.1
pkgname=swift-bin
pkgver=${_version//-/.}
pkgrel=4
pkgdesc="The Swift programming language, the binary drops from the official website"
arch=('x86_64')
url="https://swift.org"
license=('apache')
depends=('icu55' 'ncurses5-compat-libs' 'libedit' 'python2' 'libutil-linux' 'libbsd' 'clang' 'libtinfo5' 'python2-six' 'libxml2')
conflicts=('lldb' 'swift-language-git')
options=('!strip')
validpgpkeys=('1BE1E29A084CB305F397D62A9F597F4D21A56D5F')
provides=('swift-language')
replaces=('swift-language-bin')
source=(
"https://swift.org/builds/swift-${_version}-release/ubuntu1510/swift-${_version}-RELEASE/swift-${_version}-RELEASE-ubuntu15.10.tar.gz"
"https://swift.org/builds/swift-${_version}-release/ubuntu1510/swift-${_version}-RELEASE/swift-${_version}-RELEASE-ubuntu15.10.tar.gz.sig"
)
sha256sums=('6b03743e4b5182c105f80573ea0ab9e469f91553fb23a59015349c6a03a0097c'
'SKIP')
package() {
tar -C "$pkgdir" -xf "swift-${_version}-RELEASE"*.tar.gz --strip 1
# Permission fix
find "${pkgdir}" -type d -exec chmod 755 {} +
# Remove all unnecessary stuff
rm -rf "${pkgdir}/usr/local"
# Yuck! patching libedit SONAME
find "${pkgdir}/usr/bin" -type f -exec sed -i 's/libedit\.so\.2/libedit\.so\.0/g' {} \;
find "${pkgdir}/usr/lib" -type f -exec sed -i 's/libedit\.so\.2/libedit\.so\.0/g' {} \;
# remove the six.py dumped in python's site packages
rm "${pkgdir}/usr/lib/python2.7/site-packages/six.py"
# Ensure the items have the right permissions..
# some tarballs from upstream seem to have the wrong ones
find "${pkgdir}/usr/bin" -type f -exec chmod a+rx {} \;
find "${pkgdir}/usr/lib" -type f -exec chmod a+r {} \;
# Update glibc map paths
sed -i 's/\/x86_64-linux-gnu//g' "${pkgdir}/usr/lib/swift/glibc/module.map"
# Move license
install -dm755 ${pkgdir}/usr/share/licenses/${pkgname}
mv ${pkgdir}/usr/share/swift/LICENSE.txt ${pkgdir}/usr/share/licenses/${pkgname}
}
|