blob: 9ed839be23c99e0ea286565a70e999d235bc726b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Ashley Towns <mail(at)ashleytowns(dot)id(dot)au>
_version=3.0.1
pkgname=swift-bin
pkgver=${_version//-/.}
pkgrel=2
pkgdesc="The Swift programming language, the binary drops from the official website"
arch=('x86_64')
url="https://swift.org"
license=('apache')
depends=('icu55' 'ncurses5-compat-libs' 'libedit' 'python2' 'libutil-linux' 'libbsd' 'clang' 'libtinfo5' 'python2-six' 'libxml2')
conflicts=('lldb' 'swift-language-git')
options=('!strip')
validpgpkeys=('A3BAFD3556A59079C06894BD63BC1CFE91D306C6')
provides=('swift-language')
replaces=('swift-language-bin')
source=(
"https://swift.org/builds/swift-${_version}-release/ubuntu1604/swift-${_version}-RELEASE/swift-${_version}-RELEASE-ubuntu16.04.tar.gz"
"https://swift.org/builds/swift-${_version}-release/ubuntu1604/swift-${_version}-RELEASE/swift-${_version}-RELEASE-ubuntu16.04.tar.gz.sig"
)
sha256sums=('38e7ce6a716f7f72f1868b9c0ba6f29007a83e1662adb21400cca0c6c7902b58'
'0cd89ca6c8c485e9f431df16c18ad840766d3980cd3555f4fa34fb2dcff8c7e4')
package() {
tar -C "$pkgdir" -xf "swift-${_version}-RELEASE"*.tar.gz --strip 1
# Permission fix
find "${pkgdir}" -type d -exec chmod 755 {} +
# Remove all unnecessary stuff
rm -rf "${pkgdir}/usr/local"
# Yuck! patching libedit SONAME
find "${pkgdir}/usr/bin" -type f -exec sed -i 's/libedit\.so\.2/libedit\.so\.0/g' {} \;
find "${pkgdir}/usr/lib" -type f -exec sed -i 's/libedit\.so\.2/libedit\.so\.0/g' {} \;
# remove the six.py dumped in python's site packages
rm "${pkgdir}/usr/lib/python2.7/site-packages/six.py"
# Ensure the items have the right permissions..
# some tarballs from upstream seem to have the wrong ones
find "${pkgdir}/usr/bin" -type f -exec chmod a+rx {} \;
find "${pkgdir}/usr/lib" -type f -exec chmod a+r {} \;
# Move license
install -dm755 ${pkgdir}/usr/share/licenses/${pkgname}
mv ${pkgdir}/usr/share/swift/LICENSE.txt ${pkgdir}/usr/share/licenses/${pkgname}
}
|