blob: 463dfb8686f54764e60684de0a10b7ee57afc5f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Einar Lielmanis <einar@spicausis.lv>
pkgname=sylpheed-git
_gitname=sylpheed
pkgver=3.8.c47d366a
pkgrel=1
pkgdesc="Lightweight e-mail client."
arch=('i686' 'x86_64')
url="http://sylpheed.sraoss.jp/en/"
license=('GPL')
depends=('gpgme' 'gtk2' 'compface' 'gtkspell')
makedepends=('git' 'automake-1.15')
options=('libtool')
conflicts=('sylpheed' 'sylpheed-beta' 'sylpheed-beta-iconmod')
provides=('sylpheed')
source=('sylpheed::git+https://github.com/sylpheed-mail/sylpheed.git')
md5sums=('SKIP')
pkgver()
{
cd "$_gitname"
echo 3.8.$(git rev-parse --short HEAD)
}
prepare()
{
cd "$_gitname"
# fix enchant maintainers moving things around for fun
sed -i 's:enchant/enchant.h:enchant-2/enchant.h:g' src/compose.c
sed -i 's:PKG_CONFIG --libs enchant:PKG_CONFIG --libs enchant-2:g' configure.ac
}
build()
{
cd "$_gitname"
./autogen.sh --prefix=/usr --enable-ldap --enable-gpgme
make
}
package()
{
cd "$_gitname"
make DESTDIR="$pkgdir" install
}
|