PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: Salamandar <felix@piedallu.me>
# Contributor: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Martin Wimpress <code@flexion.org>
# Contributor: kozec <kozec at kozec dot com>

_pkgname=syncthing-gtk
pkgname=$_pkgname-git
pkgver=0.9.4.5.r49.g8efdb24
pkgrel=1
pkgdesc='GTK3 based GUI and notification area icon for Syncthing. Git version.'
arch=('any')
url='https://github.com/syncthing-gtk/syncthing-gtk'
license=('GPL2')
conflicts=( 'syncthing-gtk' )
makedepends=(
    'git' 'meson'
)
depends=(
    'syncthing>=0.14.50' 'gtk3' 'libnotify'
    'python3' 'python-bcrypt' 'python-dateutil' 'python-gobject' 'python-cairo'
)
source=( "git+$url" )
sha256sums=( 'SKIP' )

pkgver() {
    cd "$_pkgname"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    meson setup "$srcdir/build" "$srcdir/$_pkgname" \
        --prefix=/usr
    ninja -C "$srcdir/build"
}

package() {
    DESTDIR="$pkgdir" \
    ninja -C "$srcdir/build" install
}