blob: 4001cc4b0a1a96629e2f37402c1b3970a0625525 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Carl Smedstad <carsme@archlinux.org>
pkgname=tbls
pkgver=1.81.0
pkgrel=1
pkgdesc="CI-Friendly tool for documenting a database"
arch=(x86_64)
url="https://github.com/k1LoW/tbls"
license=(MIT)
makedepends=(go)
depends=(glibc)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('8616e136efdb1fa97f3804f65037b21c90b469c6a29f51ab3924805cce1522b6')
prepare() {
cd $pkgname-$pkgver
GOFLAGS="-mod=readonly" go mod vendor -v
}
build() {
cd $pkgname-$pkgver
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOFLAGS="-buildmode=pie -mod=vendor -modcacherw -buildvcs=false"
export GOPATH="$srcdir"
local ld_flags=" \
-compressdwarf=false \
-linkmode=external \
"
go build -v -ldflags "$ld_flags"
}
check() {
cd $pkgname-$pkgver
go test
}
package() {
cd $pkgname-$pkgver
./tbls completion bash \
| install -vDm644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/tbls"
./tbls completion fish \
| install -vDm644 /dev/stdin "$pkgdir/usr/share/fish/vendor_completions.d/tbls.fish"
./tbls completion zsh \
| install -vDm644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_tbls"
install -Dm755 -t "$pkgdir/usr/bin" tbls
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|