blob: abea00244f2c34ba7c41567d74c26ba1a5d25c35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Weng Xuetian <wengxt@gmail.com>
# Committer: Judd Vinet <jvinet@zeroflux.org>
pkgname=tcl85
pkgver=8.5.19
pkgrel=1
pkgdesc="The Tcl scripting language, 8.5 series"
arch=('i686' 'x86_64')
url="http://tcl.sourceforge.net/"
license=('custom')
source=(http://downloads.sourceforge.net/sourceforge/tcl/tcl${pkgver}-src.tar.gz)
md5sums=('4f4e1c919f6a6dbb37e9a12d429769a6')
options=('staticlibs')
build() {
cd ${srcdir}/tcl${pkgver}/unix
# we build the tcl sqlite interface in sqlite-tcl package
rm -rf ${srcdir}/tcl${pkgver}/pkgs/sqlite3*
[[ $CARCH == "x86_64" ]] && BIT="--enable-64bit"
./configure --prefix=/usr --mandir=/usr/share/man --enable-threads $BIT \
--includedir=/usr/include/tcl8.5
make
}
check() {
cd ${srcdir}/tcl${pkgver}/unix
make test
}
package()
{
cd ${srcdir}/tcl${pkgver}/unix
make INSTALL_ROOT=${pkgdir} install install-private-headers
ln -s libtcl8.5.so "${pkgdir}/usr/lib/libtcl8.5.so.0"
# install license
install -Dm644 ../license.terms ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
rm -r ${pkgdir}/usr/share/man
mv ${pkgdir}/usr/lib/tcl8/ ${pkgdir}/usr/lib/tcl8.5/
sed -i -e's:variable paths {}:variable paths {/usr/lib/tcl$(v)/tcl8}:' \
${pkgdir}/usr/lib/tcl8.5/tm.tcl
# remove buildroot traces
sed -i "s#${srcdir}#/usr/src#" ${pkgdir}/usr/lib/tclConfig.sh
mv ${pkgdir}/usr/lib/tclConfig.sh ${pkgdir}/usr/lib/tcl8.5/
# rename files
mv ${pkgdir}/usr/lib/pkgconfig/tcl.pc ${pkgdir}/usr/lib/pkgconfig/tcl85.pc
}
|